154 lines (123 with data), 4.3 kB
dnl Process this file with autoconf to produce a configure script.
AC_PREREQ(2.59)
# Making releases:
# LIBMONAPH_MICRO_VERSION += 1;
# LIBMONAPH_INTERFACE_AGE += 1;
# LIBMONAPH_BINARY_AGE += 1;
# if any functions have been added, set LIBMONAPH_INTERFACE_AGE to 0.
# if backwards compatibility has been broken,
# set LIBMONAPH_BINARY_AGE and LIBMONAPH_INTERFACE_AGE to 0.
m4_define([libmonaph_major_version], [0])
m4_define([libmonaph_minor_version], [1])
m4_define([libmonaph_micro_version], [0])
m4_define([libmonaph_real_version],
[libmonaph_major_version.libmonaph_minor_version.libmonaph_micro_version])
m4_define([libmonaph_version], [libmonaph_real_version])
m4_define([libmonaph_interface_age], [0])
m4_define([libmonaph_binary_age], [0])
m4_define([libmonaph_unstable],
m4_if(m4_eval(libmonaph_minor_version % 2), [1], [yes], [no]))
m4_define([libmonaph_full_name], [The MONA library])
AC_INIT([libmonaph], [libmonaph_version], [tittge@cbs.mpg.de])
AC_CONFIG_SRCDIR([ph/defines.hh])
AM_INIT_AUTOMAKE(no-define)
AC_CONFIG_HEADER(config.h)
LIBMONAPHPH_MAJOR_VERSION=libmonaph_major_version
LIBMONAPHPH_MINOR_VERSION=libmonaph_minor_version
LIBMONAPHPH_MICRO_VERSION=libmonaph_micro_version
LIBMONAPHPH_INTERFACE_AGE=libmonaph_interface_age
LIBMONAPHPH_BINARY_AGE=libmonaph_binary_age
LIBMONAPHPH_VERSION=libmonaph_version
LIBMONAPHPH_UNSTABLE=libmonaph_unstable
AC_SUBST(LIBMONAPHPH_MAJOR_VERSION)
AC_SUBST(LIBMONAPHPH_MINOR_VERSION)
AC_SUBST(LIBMONAPHPH_MICRO_VERSION)
AC_SUBST(LIBMONAPHPH_INTERFACE_AGE)
AC_SUBST(LIBMONAPHPH_BINARY_AGE)
AC_SUBST(LIBMONAPHPH_VERSION)
AC_SUBST(LIBMONAPHPH_UNSTABLE)
dnl The symbol LIBMONAPHPH_UNSTABLE is defined above for substitution in
dnl Makefiles and conditionally defined here as a preprocessor symbol.
if test "x$LIBMONAPHPH_UNSTABLE" = "xyes"; then
AC_DEFINE(LIBMONAPHPH_UNSTABLE,1,
[Define to 1 if this is an unstable version of the libmonaph])
fi
# libtool versioning
m4_define([lt_release], [libmonaph_major_version.libmonaph_minor_version])
m4_define([lt_current], [m4_eval(libmonaph_micro_version - libmonaph_interface_age)])
m4_define([lt_revision], [libmonaph_interface_age])
m4_define([lt_age], [m4_eval(libmonaph_binary_age - libmonaph_interface_age)])
LT_RELEASE=lt_release
LT_CURRENT=lt_current
LT_REVISION=lt_revision
LT_AGE=lt_age
LT_VERSION_INFO="lt_current:lt_revision:lt_age"
LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
AC_SUBST(LT_RELEASE)
AC_SUBST(LT_CURRENT)
AC_SUBST(LT_REVISION)
AC_SUBST(LT_AGE)
AC_SUBST(LT_VERSION_INFO)
dnl Initialize maintainer mode
AM_MAINTAINER_MODE
# some generic stuff
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_DEFINE_UNQUOTED(PLUGIN_SEARCH_PATH, "$PLUGIN_SEARCH_PATH", [Package plugin search path])
AC_SUBST(define_DEBUG_OUTPUT)
# appreciate aclocal flags
ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
dnl Initialize CC
AC_PROG_CC
AM_PROG_CC_STDC
dnl Initialize CXX
AC_PROG_CXX
dnl Initialize libtool
AC_PROG_LIBTOOL
# Checks for system header files.
AC_HEADER_DIRENT
AC_HEADER_STDC
# Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_STDBOOL
AC_C_CONST
AC_C_INLINE
AC_TYPE_SIZE_T
# Check for doxygen
AC_CHECK_PROG(have_doxygen,doxygen,"yes","no")
if test "x$have_doxygen" = "xyes"; then
AC_CHECK_PROG(HAVE_DOT,dot,"YES","NO")
AC_SUBST(HAVE_DOT)
else
AC_MSG_ERROR([
*** Doxygen is not installesd on your computer, though it is
*** required to build the documentation of this package.
*** The latest version of doxygen is always available from
*** http://www.doxygen.org])
fi
PKG_CHECK_MODULES(GLIB, "glib-2.0",, exit);
CXXFLAGS="$CXXFLAGS $GLIB_CFLAGS"
AC_SUBST(GLIB_LIBS)
dnl Checks some more functions.
AC_LANG(C++)
dnl check some boost functionality
AX_BOOST_BASE([1.33])
CXXFLAGS="$CXXFLAGS $BOOST_CPPFLAGS"
AX_BOOST_FILESYSTEM
AX_BOOST_REGEX
LIBS="$LIBS $BOOST_LDFLAGS"
dnl Set PACKAGE PREFIX
if test "x${prefix}" = "xNONE"; then
packageprefix=${ac_default_prefix}
else
packageprefix=${prefix}
fi
dnl set the standard flags for this library
libmonaph_cflags="-I$prefix/include/libmonaph-${LT_RELEASE}"
libmonaph_libs="-L$prefix/lib -lmonaph -ldl $BOOST_LDFLAGS"
AC_SUBST(libmonaph_cflags)
AC_SUBST(libmonaph_libs)
AC_CONFIG_FILES([Makefile
monaph.pc
ph/Makefile])
AC_OUTPUT