Lurch Code

49 lines (40 with data), 2.1 kB

#
# First all the usual qmake stuff
#

REDUCE_DIR = $$PWD/reduce

INCLUDEPATH += $$PWD $$REDUCE_DIR
DEPENDPATH += $$PWD $$REDUCE_DIR

DEFINES += HAVE_CONFIG_H=1 EMBEDDED=1

HEADERS += arith.h bytes.h clsyms.h config.h cslerror.h cslread.h \
	       entries.h externs.h fwin.h headers.h machine.h proc.h \
	       sockhdr.h stream.h syscsl.h tags.h termed.h version.h \
           reducedriver.h reducelob.h
SOURCES += arith01.c arith02.c arith03.c arith04.c arith05.c arith06.c \
           arith07.c arith08.c arith09.c arith10.c arith11.c arith12.c \
           bytes.c char.c embedcsl.c cslmpi.c cslread.c \
           eval1.c eval2.c eval3.c eval4.c \
           fasl.c fns1.c fns2.c fns3.c \
           fwin.c gc.c preserve.c print.c restart.c sysfwin.c termed.c \
           u01.c u02.c u03.c u04.c u05.c u06.c u07.c u08.c u09.c u10.c \
           u11.c u12.c u13.c u14.c u15.c u16.c u17.c u18.c u19.c u20.c \
           u21.c u22.c u23.c u24.c u25.c u26.c u27.c u28.c u29.c u30.c \
           u31.c u32.c u33.c u34.c u35.c u36.c u37.c u38.c u39.c u40.c \
           u41.c u42.c u43.c u44.c u45.c u46.c u47.c u48.c u49.c u50.c \
           u51.c u52.c u53.c u54.c u55.c u56.c u57.c u58.c u59.c u60.c

#
# Now the tools to import the reduce.img file to where it's needed.
#

# If you specify REDUCE_DESTDIR before including this .pri file, we'll obey that.
# Otherwise we'll put the image file where your .pro file is.
isEmpty( REDUCE_DESTDIR ): REDUCE_DESTDIR=$$OUT_PWD
# If you specify where the image file should be relative to your binary, we'll obey that.
# Otherwise we'll assume the path is ., because your binary is where your .pro is.
isEmpty( REDUCE_RELATIVE_DIR ): REDUCE_RELATIVE_DIR=$$REDUCE_DESTDIR
DEFINES += REDUCE_IMAGE="\\\"$${REDUCE_RELATIVE_DIR}/reduce.img\\\""
# Now copy the image there in a platform-specific way.
win32: {
    REDUCE_DIR = $$replace(REDUCE_DIR,"/","\\")
    REDUCE_DESTDIR = $$replace(REDUCE_DESTDIR,"/","\\")
    system(copy $$REDUCE_DIR\\reduce.img $$REDUCE_DESTDIR)
}
!win32: system(rsync $$REDUCE_DIR/reduce.img $$REDUCE_DESTDIR)