Continuation Core and Toolboxes (COCO) Code

128 lines (103 with data), 3.7 kB

#!/bin/tcsh
# add file(s) to admin areas of all sub-projects

set dn = "${0:t}"

test -d ../../core/admin || echo "${dn}: must be run from within core/admin" && exit 1

set URL  = `svn info | grep URL`
set AURL = $URL[2]
set ROOT = $AURL:h:h:h
set pushdsilent

set files = ( $argv[1-]:q )
set fls   = `scripts/quote $files:q`

# initialise logged execution
# set exec_debug
source scripts/exec_logged_init "$dn" || exit 1

# ###################################################################################
# add admin files to covering
echo "adding new admin scripts/files to toolbox covering"

# checkout admin
set cmd = "svn checkout ${ROOT}/covering/code/trunk/admin tmp_admin"
source scripts/exec_logged "$cmd" || exit 1

# create directories and copy files
foreach f ( $files:q )
	set fq = `scripts/quote $f:q`
	if ( -ed $f ) then
		set cmd = "svn mkdir $fq"
		source scripts/exec_logged "$cmd" tmp_admin || exit 1
	else
		set dst = `scripts/quote tmp_admin/$f:q`
		set cmd = "cp $fq $dst"
		source scripts/exec_logged "$cmd" || exit 1
	endif
end

# add files
set cmd = "svn add $fls"
source scripts/exec_logged "$cmd" tmp_admin || exit 1
set msg = `scripts/quote "${dn}: added admin scripts/files to covering"`
set cmd = "svn commit $fls -m $msg"
source scripts/exec_logged "$cmd" tmp_admin || exit 1

# remove tmp_admin
set cmd = "rm -rf tmp_admin"
source scripts/exec_logged "$cmd" || exit 1

# ###################################################################################
# update admin files of toolboxes
set auto = ( `cat tb_lst_auto.txt` )

foreach p ( $auto )
	echo "adding new admin scripts/files to toolbox $p"

	# checkout admin
	set cmd = "svn checkout ${ROOT}/auto/${p}/trunk/admin tmp_admin"
	source scripts/exec_logged "$cmd" || exit 1
	
	# create directories and copy files
	foreach f ( $files:q )
		set fq = `scripts/quote $f:q`
		if ( -ed $f ) then
			set cmd = "svn mkdir $fq"
			source scripts/exec_logged "$cmd" tmp_admin || exit 1
		else
			set dst = `scripts/quote tmp_admin/$f:q`
			set cmd = "cp $fq $dst"
			source scripts/exec_logged "$cmd" || exit 1
		endif
	end

	# add files
	set cmd = "svn add $fls"
	source scripts/exec_logged "$cmd" tmp_admin || exit 1
	set msg = `scripts/quote "${dn}: added admin scripts/files to ${p}"`
	set cmd = "svn commit $fls -m $msg"
	source scripts/exec_logged "$cmd" tmp_admin || exit 1
	
	# remove tmp_admin
	set cmd = "rm -rf tmp_admin"
	source scripts/exec_logged "$cmd" || exit 1
end

# ###################################################################################
# update admin files of flagship examples
set exas = ( `cat tb_lst_exas.txt` )

foreach p ( $exas )
	echo "adding new admin scripts/files to example $p"

	# checkout admin
	set cmd = "svn checkout ${ROOT}/examples/$p/trunk/admin tmp_admin"
	source scripts/exec_logged "$cmd" || exit 1
	
	# create directories and copy files
	foreach f ( $files:q )
		set fq = `scripts/quote $f:q`
		if ( -ed $f ) then
			set cmd = "svn mkdir $fq"
			source scripts/exec_logged "$cmd" tmp_admin || exit 1
		else
			set dst = `scripts/quote tmp_admin/$f:q`
			set cmd = "cp $fq $dst"
			source scripts/exec_logged "$cmd" || exit 1
		endif
	end

	# commit files
	set cmd = "svn add $fls"
	source scripts/exec_logged "$cmd" tmp_admin || exit 1
	set msg = `scripts/quote "${dn}: added admin scripts/files to ${p}"`
	set cmd = "svn commit $fls -m $msg"
	source scripts/exec_logged "$cmd" tmp_admin || exit 1
	
	# remove tmp_admin
	set cmd = "rm -rf tmp_admin"
	source scripts/exec_logged "$cmd" || exit 1
end

# ###################################################################################
# success: remove log file
source scripts/exec_logged_exit