Xournal Code

59 lines (47 with data), 1.4 kB

dnl Process this file with autoconf to produce a configure script.

AC_INIT(configure.in)
AM_INIT_AUTOMAKE(xournal, 0.4.8.2016)
AC_CONFIG_HEADERS(config.h)
AM_MAINTAINER_MODE

AC_ISC_POSIX
AC_PROG_CC
AC_PROG_RANLIB
AM_PROG_AR
AC_HEADER_STDC

LDFLAGS="$LDFLAGS -lz -lm"

ifdef([PKG_CHECK_MODULES], [[]], [m4_fatal([Module checker (pkg-config or pkgconf) is required but doesn't seem to be installed.])])

pkg_modules="gtk+-2.0 >= 2.10.0 libgnomecanvas-2.0 >= 2.4.0 poppler-glib >= 0.5.4 pangoft2 >= 1.0"
PKG_CHECK_MODULES(PACKAGE, [$pkg_modules])
AC_SUBST(PACKAGE_CFLAGS)
AC_SUBST(PACKAGE_LIBS)

dnl detect Windows environment...
AC_CANONICAL_HOST
AC_MSG_CHECKING([for Windows environment])
case "$host" in
 *-*-mingw*)
   os_win32=yes;;
 *)
   os_win32=no;;
esac
AC_MSG_RESULT([$os_win32])
AM_CONDITIONAL(WIN32, test "$os_win32" = "yes")

dnl test for Linux, so we can add -lX11 manually for broken distributions
case "$host" in
 *-*-linux*)
   os_linux=yes;;
 *)
   os_linux=no;;
esac
AM_CONDITIONAL(LINUX, test "$os_linux" = "yes")

GETTEXT_PACKAGE=xournal
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])

dnl Add the languages which your application supports here.
ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
AM_GLIB_GNU_GETTEXT

AC_OUTPUT([
Makefile
src/Makefile
src/ttsubset/Makefile
po/Makefile.in
])